
Preface

What is Prolog?
Programming in Logic. 
Edinburgh syntax is the basis of ISO standard. 
High-level interactive language. 
Logic Programming Language
Based on Horn clauses

What are strengths and Weaknesses?

Good at

Grammars and Language processing

Knowledge representation and reasoning

Pattern matching

Symbolic AI

Poor at

Repetitive number crunching

Input/Output

Section 1: Introduction
 

The Compiler

 

A disk with Visual Prolog 7.1 Personal Edition will be distributed in class. It will also be placed on selected computers in the lab.
(  Run setup to install the program - works under XP and Vista

(  To create a link to the executable (assuming you accepted the default locations) go to 
    c:\program files.\visual prolog 7.1\bin\vip
(  When the program opens, click on Help at the top, then Visual Prolog Help - good 
    explanations are provided

 

Visual Prolog is object oriented, strictly typed and mode checked.  You will of course have to master all this to write Visual Prolog programs.  But here we will focus on the core of the code, i.e. the code when disregarding classes, types and modes.
For this purpose we will use the PIE example that is included in the Visual Prolog distribution.  PIE is a "classical" Prolog interpreter, by using this you can learn and experiment with Prolog without being concerned with classes, types, etc.

Horn Clause Logic

Visual Prolog and other Prolog dialects are based on Horn Clause logic.  Horn Clause logic is a formal system for reasoning about things and the way they relate to each other. In natural language I can express a statement like:
John is the father of Bill.

 

Here I have two "things": John and Bill, and a "relation" between these, namely that one is the father of the other. In Horn Clause Logic I can formalize this statement in the following way:

 

father("Bill", "John").

 
father is a predicate/relation taking two arguments, where the second is the father of the first.  Notice that I have chosen that the second person should be the father of the first. I might as well have chosen it the other way around: The order of the arguments is the choice of the "designer" of the formalization. However, once you have chosen, you must be consistent. So in my formalization the father must always be the second person.

I have chosen to represent the persons by their names (which are string literals). In a more complex world this would not be sufficient because many people have same name. But for now we will be content with this simple formalization.

 

With formalizations like the one above I can state any kind of family relation between any persons. But for this to become really interesting I will also have to formalize rules like this:

 

X is the grandfather of Z, if X is the father of Y and Y is the father of Z

where X, Y and Z are persons. In Horn Clause Logic I can formalize this rule like this:

 

grandFather(Person, GrandFather) :-

    father(Person, Father), father(Father, GrandFather).

 

I have chosen to use variable names that help understanding better than X, Y and Z. I have also introduced a predicate for the grandfather relation. Again I have chosen that the grandfather should be the second argument. It is wise to be consistent like that, i.e. that the arguments of the different predicates follow some common principle. 

 

When reading rules you should interpret :- as if and the comma that separates the relations as and.

 

Statements like "John is the father of Bill" are called facts, while statements like "X is the grandfather of Z, if X is the father of Y and Y is the father of Z" are called rules.

With facts and rules we are ready to formulate theories. A theory is a collection of facts and rules. Let me state a little theory:

 

father("Bill", "John").

father("Pam", "Bill").

grandFather(Person, GrandFather) :-

    father(Person, Father),

    father(Father, GrandFather).

 

The purpose of the theory is to answer questions like these:

 

Is John the father of Sue?

Who is the father of Pam?

Is John the grandfather of Pam?

 

Such questions are called goals. And they can be formalized like this (respectively):

 

?- father("Sue", "John").

?- father("Pam", X).

?- grandFather("Pam", "John").

 

Such questions are called goal clauses or simply goals. Together facts, rules and goals are called Horn clauses, hence the name Horn Clause Logic.

Some goals like the first and last are answered with a simple yes or no. For other goals like the second we seek a solution, like X = "Bill".

Some goals may even have many solutions. For example:

 

?- father(X, Y).

has two solutions:

X = "Bill", Y = "John".

X = "Pam", Y = "Bill".

 

A Prolog program is a theory and a goal. When the program starts it tries to find a solution to the goal in the theory.

 

PIE: Prolog Inference Engine

 

Now we will try the little example above in PIE, the Prolog Inference Engine. That comes with Visual Prolog.

 

Before we start you should install and build the PIE example.
(  Select "Install Examples" in the Windows start menu (Start -> Visual Prolog -> 
    Install Examples). 

(  Open the PIE project in the VDE and run the program, as it is described in Tutorial 
    01: Environment Overview

When the program starts it will look like this:

Select File -> New and enter the father and grandFather clauses above:

File -> New and enter the father and grandFather clauses above:

While the editor window is active choose Engine -> Reconsult. This will load the file into the engine. In the Dialog window you should receive a message like this:

 

Reconsulted from: ....\pie\Exe\FILE4.PRO

 

Reconsult loads whatever is in the editor, without saving the contents to the file, if you want to save the contents use File -> Save.

 

File -> Consult will load the disc contents of the file regardless of whether the file is opened for editing or not.

 

Once you have "consulted" the theory, you can use it to answer goals.

On a blank line in the Dialog window type a goal (without the ?- in front).

For example:
[image: image3.jpg]FLUNESSSS . =

grandFather(X,Y)|





 

When the caret is placed at the end of the line, press the Enter key on your keyboard. PIE will now consider the text from the beginning of the line to the caret as a goal to execute. You should see a result like this:

Extending the Family Theory

 

It is straight forward to extend the family theory above with predicates like mother and grandMother. You should try that yourself. You should also add more persons. I suggest that you use persons from your own family, because that makes it lot easier to validate, whether some person is in deed the grandMother of some other person, etc.

 

Given mother and father we can also define a parent predicate. You are a parent if you are a mother; you are also a parent if you are a father. Therefore we can define parent using two clauses like this:

 

parent(Person, Parent) :- mother(Person, Parent).

parent(Person, Parent) :- father(Person, Parent).

 

The first rule reads (recall that the second argument corresponds to the predicate name):

 

Parent is the parent of Person, if Parent is the mother of Person

You can also define the parent relation using semicolon ";" which means or, like this:

 

parent(Person, Parent) :-

    mother(Person, Parent);

    father(Person, Parent).

 

This rule reads:
Parent is the parent of Person, if Parent is the mother of Person or Parent is the father of Person

 

I will however advise you to use semicolon as little as possible (or actually not at all). There are several reasons for this:
· The typographical difference "," and ";" is very small, but the semantic difference is rather big. ";" is often a source of confusion, since it is easily misinterpreted as ",", especially when it is on the end of a long line. 

· Visual Prolog only allows you to use semicolon on the outermost level (PIE will allow arbitrarily deep nesting). 

 

Try creating a sibling predicate! Did that give problems?

You might find that siblings are found twice. At least if you say: Two persons are siblings if they have same mother, two persons are also siblings if they have same father. I.e. if you have rules like this:

 

sibling(Person, Sibling) :- mother(Person, Mother), mother(Sibling, Mother).

sibling(Person, Sibling) :- father(Person, Father), father(Sibling, Father).

 

The first rule reads:

 

Sibling is the sibling of Person, if Mother is the mother of Person and Mother is the mother of Sibling

 

The reason that you receive siblings twice is that most siblings both have same father and mother, and therefore they fulfill both requirements above. And therefore they are found twice.

 

We shall not deal with this problem now; currently we will just accept that some rules give too many results.

 

A fullBlodedSibling predicate does not have the same problem, because it will require that both the father and the mother are the same:

 

fullBlodedSibling(Person, Sibling) :-

    mother(Person, Mother),

    mother(Sibling, Mother),

    father(Person, Father),

    father(Sibling, Father).

 

Prolog is a Programming Language
 

From the description so far you might think that Prolog is an expert system, rather than a programming language. And indeed Prolog can be used as an expert system, but it is designed to be a programming language.
We miss two important ingredients to turn Horn Clause logic into a programming language:

 

· Rigid search order/program control 

· Side effects 

 

Program Control

 

When you try to find a solution to a goal like:

 

?- father(X, Y).
You can do it in many ways. For example, you might just consider at the second fact in the theory and then you have a solution.

 

But Prolog does not use a "random" search strategy, instead it always use the same strategy. The system maintains a current goal, which is always solved from left to right.

 

i.e. if the current goal is:

 

?- grandFather(X, Y), mother(Y, Z).

 

Then the system will always try to solve the sub-goal grandFather(X, Y) before it solves mother(Y, Z), if the first (i.e. left-most) sub-goal cannot be solved then there is no solution to the overall problem and then the second sub-goal is not tried at all.

When solving a particular sub-goal, the facts and rules are always tried from top to bottom.

 

When a sub-goal is solved by using a rule, the right hand side replaces the sub-goal in the current goal.

 

i.e. if the current goal is:

 

?- grandFather(X, Y), mother(Y, Z).

 And we are using the rule

 

grandFather(Person, GrandFather) :- father(Person, Father), father(Father, GrandFather).

 

to solve the first sub-goal, then the resulting current goal will be:

 

?- father(X, Father), father(Father, Y), mother(Y, Z).

 

Notice that some variables in the rule have been replaced by variables from the sub-goal. I will explain the details later.

 

Given this evaluation strategy you can interpret clauses much more procedural. Consider this rule:

 

grandFather(Person, GrandFather) :- father(Person, Father), father(Father, GrandFather).

 

Given the strict evaluation we can read this rule like this:
To solve grandFather(Person, GrandFather) first solve father(Person, Father) and then solve father(Father, GrandFather).

Or even like this:

When grandFather(Person, GrandFather) is called, first call father(Person, Father) and then call father(Father, GrandFather).

With this procedural reading you can see that predicates correspond to procedures/subroutines in other languages. The main difference is that a Prolog predicate can return several solutions to a single invocation or even fail. This will be discussed in details in the next sections.

 

Failing

 

A predicate invocation might not have any solution in the theory, for example calling parent("Hans", X) has no solution as there are no parent facts or rules that applies to "Hans". We say that the predicate call fails. If the goal fails then there is simply no solution to the goal in the theory. The next section will explain how failing is treated in the general case, i.e. when it is not the goal that fails.

 

Backtracking

 

In the procedural interpretation of a Prolog program "or" is treated in a rather special way. Consider the clause

 

parent(Person, Parent) :-

    mother(Person, Parent);

    father(Person, Parent).

 

In the logical reading we interpreted this clause as:

Parent is the parent of Person if Parent is the mother of Person or Parent is the father of Person.

The "or" introduces two possible solutions to an invocation of the parent predicate. Prolog handles such multiple choices by first trying one choice and later (if necessary) backtracking to the next alternative choice, etc.

 

During the execution of a program a lot of alternative choices (known as backtrack points) might exist from earlier predicate calls. If some predicate call fails, then we will backtrack to the last backtrack point we met and try the alternative solution instead. If no further backtrack points exists then the overall goal has failed, meaning that there was no solution to it.

 

With this in mind we can interpret the clause above like this:

When parent(Person, Parent) is called first record a backtrack point to the second alternative solution (i.e. to the call to father(Person, Parent)) and then call mother(Person, Parent)

 

A predicate that has several classes behave in a similar fashion. Consider the clauses:

 

father("Bill", "John").

father("Pam", "Bill").

 

When father is invoked we first record a backtrack point to the second clause, and then try the first clause.

If there are three or more choices we still only create one backtrack point, but that backtrack point will start by creating another backtrack point. Consider the clauses:

 

father("Bill", "John").

father("Pam", "Bill").

father("Jack", "Bill").

 

When father is invoked, we first record a backtrack point. And then we try the first clause. The backtrack point we create points to some code, which will itself create a backtrack point (namely to the third clause) and then try the second clause. Thus all choice points have only two choices, but one choice might itself involve a choice.

 

Example To illustrate how programs are executed I will go through an example in details. Consider these clauses:

 

mother("Bill", "Lisa").

father("Bill", "John").

father("Pam", "Bill").

father("Jack", "Bill").

parent(Person, Parent) :-

    mother(Person, Parent);

    father(Person, Parent).

 

And then consider this goal:

 

?- father(AA, BB), parent(BB, CC).

 

This goal states that we want to find three persons AA, BB and CC, such that BB is the father of AA and CC is a parent of BB.

 

As mentioned we always solve the goals from left to right, so first we call the father predicate. When executing the father predicate we first create a backtrack point to the second clause, and then use the first clause.
Using the first clause we find that AA is "Bill" and BB is "John". So we now effectively have the goal:

 

?- parent("John", CC).

 

So we call parent, which gives the following goal:

 

?- mother("John", CC); father("John", CC).

 

You will notice that the variables in the clause have been replaced with the actual parameters of the call (exactly like when you call subroutines in other languages).
The current goal is an "or" goal, so we create a backtrack point to the second alternative and pursuit the first. We now have two active backtrack points, one to the second alternative in the parent clause, and one to the second clause in the father predicate.

After the creation of this backtrack point we are left with the following goal:

 

?- mother("John", CC).
So we call the mother predicate. The mother predicate fails when the first argument is "John" (because it has no clauses that match this value in the first argument).
In case of failure we backtrack to the last backtrack point we created. So we will now pursuit the goal:

 

?- father("John", CC).

 

When calling father this time, we will again first create a backtrack point to the second father clause.

 

Recall that we also still have a backtrack point to the second clause of the father predicate, which corresponds to the first call in the original goal.

 

We now try to use the first father clause on the goal, but that fails, because the first arguments do not match (i.e. "John" does not match "Bill").

 

Therefore we backtrack to the second clause, but before we use this clause we create a backtrack point to the third clause.

 

The second clause also fails, since "John" does not match "Pam", so we backtrack to the third clause. This also fails, since "John" does not match "Jack".

 

Now we must backtrack all the way back to the first father call in the original goal; here we created a backtrack point to the second father clause.

Using the second clause we find that AA is "Pam" and BB is "Bill". So we now effectively have the goal:

 

?- parent("Bill", CC).

 

When calling parent we now get:

 

?- mother("Bill", CC); father("Bill", CC).

 

Again we create a backtrack point to the second alternative and pursuit the first:

?- mother("Bill", CC).

This goal succeeds with CC being "Lisa". So now we have found a solution to the goal:

AA = "Pam", BB = "Bill", CC = "Lisa".

When trying to find additional solutions we backtrack to the last backtrack point, which was the second alternative in the parent predicate:

?- father("Bill", CC).

This goal will also succeed with CC being "John". So now we have found one more solution to the goal:

AA = "Pam", BB = "Bill", CC = "John".

If we try to find more solutions we will find

AA = "Jack", BB = "Bill", CC = "John".

AA = "Jack", BB = "Bill", CC = "Lisa".

After that we will experience that everything will eventually fail leaving no more backtrack points. So all in all there are four solutions to the goal.

Improving the Family Theory

 

If you continue to work with the family relation above you will probably find out that you have problems with relations like brother and sister, because it is rather difficult to determine the sex of a person (unless the person is a father or mother).

The problem is that we have chosen a bad way to formalize our theory.

The reason that we arrived at this theory is because we started by considering the relations between the entities. If we instead first focus on the entities, then the result will naturally become different.
Our main entities are persons. Persons have a name (in this simple context will still assume that the name identifies the person, in a real scale program this would not be true). Persons also have a sex. Persons have many other properties, but none of them have any interest in our context.
Therefore we define a person predicate, like this:
person("Bill", "male").

person("John", "male").

person("Pam", "female").

The first argument of the person predicate is the name and the second is the sex.

Instead of using mother and father as facts, I will choose to have parent as facts and mother and father as rules:
parent("Bill", "John").

parent("Pam", "Bill").
father(Person, Father) :- parent(Person, Father), person(Father, "male").

Notice that when father is a "derived" relation like this, it is impossible to state female fathers. So this theory also has a built-in consistency on this point, which did not exist in the other formulation.

 

Recursion

 

Most family relations are easy to construct given the principles above. But when it comes to "infinite" relations like ancestor we need something more. If we follow the principle above, we should define ancestor like this:
ancestor(Person, Ancestor) :- parent(Person, Ancestor).

ancestor(Person, Ancestor) :- parent(Person, P1), parent(P1, Ancestor).

ancestor(Person, Ancestor) :- parent(Person, P1), parent(P1, P2), parent(P2, Ancestor).

...

The main problem is that this line of clauses never ends. The way to overcome this problem is to use a recursive definition, i.e. a definition that is defined in terms of itself. like this:
ancestor(Person, Ancestor) :- parent(Person, Ancestor).

ancestor(Person, Ancestor) :- parent(Person, P1), ancestor(P1, Ancestor).
This declaration states that a parent is an ancestor, and that an ancestor to a parent is also an ancestor.
If you are not already familiar with recursion you might find it tricky (in several senses). Recursion is however fundamental to Prolog programming. You will use it again and again, so eventually you will find it completely natural.
Let us try to execute an ancestor goal:
?- ancestor("Pam", AA).
We create a backtrack point to the second ancestor clause, and then we use the first, finding the new goal:
?- parent("Pam", AA).
This succeeds with the solution:
AA = "Bill".

Then we try to find another solution by using our backtrack point to the second ancestor clause. This gives the new goal:
?- parent("Pam", P1), ancestor(P1, AA).
Again "Bill" is the parent of "Pam",so we find P1= "Bill", and then we have to goal:
?- ancestor("Bill", AA).
To solve this goal we first create a backtrack point to the second ancestor clause and then we use the first one. This gives the following goal
?- parent("Bill", AA).
This goal has the gives the solution:
AA = "John".
So now we have found two ancestors of "Pam": "Bill" and "John".

If we use the backtrack point to the second ancestor clause we get the following goal:
?- parent("Bill", P1), ancestor(P1, AA).
Here we will again find that "John" is the parent of "Bill", and thus that P1 is "John". This gives the goal:
?- ancestor("John", AA).
If you pursuit this goal you will find that it will not have any solution. So all in all we can only find two ancestors of "Pam".
Recursion is very powerful but it can also be a bit hard to control. Two things are important to remember:
· the recursion must make progress 

· the recursion must terminate 

In the code above the first clause ensures that the recursion can terminate, because this clause is not recursive (i.e. it makes no calls to the predicate itself).
In the second clause (which is recursive) we have made sure, that we go one ancestor-step further back, before making the recursive call. I.e. we have ensured that we make some progress in the problem.

 

Side Effects
 

Besides a strict evaluation order Prolog also has side effects. For example Prolog has a number of predefined predicates for reading and writing. The following goal will write the found ancestors of "Pam":
?- ancestor("Pam", AA), write("Ancestor of Pam : ", AA), nl().
The ancestor call will find an ancestor of "Pam" in AA.
The write call will write the string literal "Ancestor of Pam : ", and then it will write the value of AA.
The nl call will shift to a new line in the output.
When running programs in PIE, PIE itself writes solutions, so the overall effect is that your output and PIE's own output will be mixed. This might of course not be desirable.

A very simple way to avoid PIE's own output is to make sure that the goal has no solutions. Consider the following goal:
?- ancestor("Pam", AA), write("Ancestor of Pam : ", AA), nl(), fail.
fail is a predefined call that always fails (i.e. it has no solutions).
The first three predicate calls have exactly the same effect as above: an ancestor is found (if such one exists, of course) and then it is written. But then we call fail this will of course fail. Therefore we must pursuit a backtrack point if we have any.

When pursuing this backtrack point, we will find another ancestor (if such one exists) and write that, and then we will fail again. And so forth.
So, we will find and write all ancestors. and eventually there will be no more backtrack points, and then the complete goal will fail.

There are a few important points to notice here:
· The goal itself did not have a single solution, but nevertheless all the solutions we wanted was given as side effects. 

· Side effects in failing computations are not undone. 

 

These points are two sides of the same thing. But they represent different level of optimism. The first optimistically states some possibilities that you can use, while the second is more pessimistic and states that you should be aware about using side effects, because they are not undone even if the current goal does not lead to any solution.
Anybody, who learns Prolog, will sooner or later experience unexpected output coming from failing parts of the program. Perhaps, this little advice can help you: Separate the "calculating" code from the code that performs input/output.
In our examples above all the stated predicate are "calculating" predicates. They all calculate some family relation. If you need to write out, for example, "parents", create a separate predicate for writing parents and let that predicate call the "calculating" parent predicate.

Conclusion

 

In this tutorial we have looked at some of the basic features of Prolog. You have seen facts, rules and goals. You learned about the execution strategy for Prolog including the notion of failing and backtracking. You have also seen that backtracking can give many results to a single question. And finally you have been introduced to side effects.

 Section 2:  A First Example
Open Visual Prolog

At top of page, select Project Open. Go to directory containing Visual Prolog Examples, open PIE directory, select PIE application. The following screen will appear.

At top of page, select Build, then Execute. When asked if want to register program, select Continue Evaluation. Click that you understand the program cannot be distributed commercially. You will then see the following screen.

At top of page, select File, New. On the screen provided, type the following

father("Bill", "John").

father("Pam", "Bill").

grandFather(Person, GrandFather):-

  father(Father, GrandFather), father(Person, Father). 

At top of page, select Engine, Reconsult

At top of page, select File, Consult. Highlight the file you are working on (FILE0 in this case) and click Open - as shown below.

In the Dialog box (open the Dialog box by selecting Window, Dialog type the following 

    father("Sue", "John"). 

Press Return

In the Dialog box type the following

    father(X,Y).

Press return

Output for each query is presented below.

Section 3: Getting Started

In this tutorial we just want to have a first shot at running Prolog... 

Typing in a Prolog program
Firstly, we want to type in a Prolog program and save it in a file, so, using a Text Editor, type in the following program: 

likes(mary,food).


likes(mary,wine).


likes(john,wine).


likes(john,mary).

Try to get this exactly as it is - don't add in any extra spaces or punctuation, and don't forget the full-stops: these are very important to Prolog. Also, don't use any capital letters - not even for people's names. Make sure there's at least one fully blank line at the end of the program. 

Once you have typed this in, save it as intro.pl 

(Prolog files usually end with ".pl", just as C files end with ".c") 

Starting Prolog

Start Prolog at the command prompt; to start GNU Prolog you just type in gprolog. After a while, you should get something like the following on screen: 

Copyright (C) 1999-2004 Daniel Diaz

| ?-
The Prolog interpreter is now running and waiting for you to type in some commands. 

Loading the Program
	Writing programs in Prolog is a cycle involving

1. Write/Edit the program in a text-editor 

2. Save the program in the text editor 

3. Tell Prolog to read in the program 

4. If Prolog gives you errors, go back to step 1 and fix them 

5. Test it - if it doesn't do what you expected, go back to step 1 


We've done the first two of these, so now we need to load the program into Prolog. 

The program has been saved as "intro.pl", so in your Prolog window, type the following and hit the return key: 

Don't forget the full-stop at the end of this! 

This tells Prolog to read in the file called intro.pl - you should do this every time you change your program in the text editor. (If your program was called something else, like "other.pl", you'd type "other" instead of "intro" above). 

You should now have something like the following on screen 

| ?- [intro].

compiling /home/jpower/intro.pl for byte code...

/home/jpower/intro.pl compiled, 5 lines read - 554 bytes written, 7 ms

yes

| ?- 
The "yes" at the end indicates that Prolog has checked your code and found no errors. If you get anything else (particularly a "no"), you should check that you have typed in the code correctly. 

At any stage, you can check what Prolog has recorded by asking it for a listing: 

| ?- listing.

likes(mary, food).

likes(mary, wine).

likes(john, wine).

likes(john, mary).

yes

| ?-

Running a query
We can now ask Prolog about some of the information it has just read in; try typing each of the following, hitting the return key after each one (and don't forget the full-stop at the end: Prolog won't do anything until it sees a full-stop) 

· likes(mary,food). 

· likes(john,wine). 
· likes(john,food). 
When you're finished you should leave Prolog by typing halt.
Section 4: Facts and Rules

Since we've just met facts and rules, we want to get some practice with using them. 

The Rules

The program we wrote in the last tutorial was a fairly small one, so we won't be adding many rules. 

Test your program by loading it into Prolog after each modification, and running the following queries against it: 

· likes(john,X). 
· likes(mary,X). 
· likes(Y,food). 
· likes(Y,wine). 
(Do this now, before you change anything!) 

The difference between facts and rules is that rules are conditional, and use Prolog's "if" operator. 

For the moment, we'll just be using three operators in Prolog: 

	Operator
	Meaning

	:-
	if

	,
	and

	;
	or


Open the file in the text editor and try adding in rules to express the following: 

· John likes anything that Mary likes
Phrase this as: John likes something if Mary likes something 

· John likes anyone who likes wine
Phrase this as: John likes someone if that someone likes wine 

· John likes anyone who likes themselves 

Do these one at a time, testing the above queries each time 

The Family Tree Example

Suppose that we want to represent a family tree, so that we can ask questions like "is John related to ...", or "list all John's sisters" and so on. 

The basic entities will be people; the properties we will want to look at will be father, mother, brother, sister, ..... We choose three basic predicates, male, female and parent, which will describe a family by a series of facts. 

Take the following family tree as an example: 

                              James I

                                 |

                                 |

                +----------------+-----------------+

                |                                  |

             Charles I                          Elizabeth

                |                                  |

                |                                  |

     +----------+------------+                     |

     |          |            |                     |

 Catherine   Charles II   James II               Sophia

                                                   |

                                                   |

                                                   |

                                                George I

In Prolog we represent this as: 

  % male(P) is true when P is male

  male(james1).

  male(charles1).

  male(charles2).

  male(james2).

  male(george1).

  % female(P) is true when P is female

  female(catherine).

  female(elizabeth).

  female(sophia).

  % parent(C,P) is true when C has a parent called P

  parent(charles1, james1).

  parent(elizabeth, james1).

  parent(charles2, charles1).

  parent(catherine, charles1).

  parent(james2, charles1).

  parent(sophia, elizabeth).

  parent(george1, sophia).

Start a new file in your text editor (call it "family.pl"), and copy and paste the above program into it. 

We can now formulate some queries (try entering these yourself): 

· Was George I the parent of Charles I? 
Query: parent(charles1, george1). 
· Who was Charles I's parent?
Query: parent(charles1, Parent). 

· Who were the children of Charles I?
Query: parent(Child, charles1). 

Try adding the following rules to the program, and check the results: 

· M is the mother of P if she is a parent of P and is female 

· F is the father of P if he is a parent of P and is male 

· X is a sibling of Y if they both have the same parent. 

Remember that "and" in Prolog is represented using a comma. Also, the connection between predicates should be made by sharing variables (and not by embedding one predicate inside another). 

If you get this done, can you add rules for: 

· "sister", "brother", 

· "aunt", "uncle", 

· "grandparent", "cousin" 

Section 5: Operators and Arithmetic

This week we just want to get some more practice with writing and querying knowledge bases, and look a little closer at how Prolog works. In particular, we want to emphasise that Prolog deals with relations and not functions, and demonstrate this by looking at how Prolog deals with arithmetic. 

Some Prolog Details

In this section we want to emphasise a few points, some of which you might have come up against in last week's tutorial. 

Arity

You have probably noticed that Prolog's error messages always refer to a predicate name along with a number; for example likes/2 in last week's example. The number given with each predicate is called its arity. 

The arity of a predicate is simply the number of arguments it takes. 

The reason Prolog always refers to the arity is that Prolog allows you to have different predicates with the same name, but different arity. Thus you could define two totally different predicates with the same name but a different number of "parameters"; when you called one of them, Prolog would count the number of arguments, and reference the appropriate definition. It's not really a good idea to do this (as it can be confusing), but it might help explain some seemingly strange errors in your input! 

Spaces
While we're on the subject, another common source of error in defining a predicate is putting spaces in the wrong place. Basically, Prolog doesn't really mind how you lay out your code (you can add extra spaces and carriage-returns almost anywhere) with one main exception: 

· when defining or calling a predicate, you should not put a space between the name of the predicate and the opening bracket - "(" - which follows it. 

Comments

As you write more knowledge bases, you may want to comment them for your own reference; two forms of comment are allowed in Prolog: 

1. The character "%" followed by any sequence of characters up to end of line. 

2. The symbols "/*" followed by any sequence of characters (including new lines) up to "*/" 

Simple I/O in Prolog

We'll be looking at I/O in a little more detail later, but for the moment you should know about the following predicates: 

· nl which moves to a new line on screen 

· write(X) which writes X on screen 

Arithmetic in Prolog

In this section we want to look at how Prolog deals with numbers; an important point here is the difference between functions (as in C) and Prolog's relations. 

Built-In Predicates

To date we have been defining our own predicates as we needed them. As you might expect, many commonly-used predicates are built in to Prolog, and we can use these in our programs. Because these are part of the language we can use them like a normal relation (i.e. write them between their arguments), instead of having to write them before their arguments. (for the record, the former is called infix, the latter is called prefix). There are ways of making your own infix predicates, but we won't worry about this for the moment.

The built-in arithmetical predicates are the obvious ones: <, >, >=, =<, = etc. A simple example of their use would be the following two predicates: 

  positive(N) :- N>0.

  non_zero(N) :- N<0 ; N>0.

Note that Prolog's "=" relation is equality (not assignment); it is the same as the "==" relation in C.

Arithmetic Operators

Prolog also has arithmetic operators like +, -, *, / and also the usual collection of functions like sqrt, exp, cos. However these do not work exactly as expected!

The important point here is to realise that writing "2+3" in Prolog is not an instruction to carry out the addition (remember, Prolog is not an imperative language). Rather it represents "the addition of 2 and 3". It is thus a completely different term to "1+4", or "3+2", and certainly different from "5*1" etc. 

Thus if we have the knowledge base: 

  prime(2).

  prime(3).

  prime(5).

  ...

The queries "prime(1+1)" or "prime(5*1)" will both fail, because the terms they contain cannot be unified with any of those in the knowledge base. 

The value of an arithmetic expression is only actually computed when we ask Prolog to compute it - the standard way of doing is to use Prolog's assignment predicate is. 

· The predicate "N is E" will succeed whenever N is an unbound variable, and E is some arithmetic expression (like 2+3). After it succeeds, N will be assigned the computed value of E. 

Thus, in the above example, the query "X is 1+1, prime(X)." would succeed, since the is will cause the term 1+1 to be evaluated to 2. 

It's worth emphasising this point: in general, the variable used before the is should be unbound; any variables occurring in the arithmetical expression should have a value. 

So, to use one of the built-in arithmetic functions, you'd need something like: 

| ?- X is sqrt(9),  Y is 2 ** 4,  Z is floor(3.14).

X = 3.0

Y = 16.0

Z = 3
Some queries:
Each of the following can be entered as a query to Prolog. Try entering them, and make sure you understand Prolog's response in each case: 

· N is 1+1. 

· N is 1+1, P is N*2, Q is P+Q. 

· N is X+1. 

· I is I+1. 

· I is 6, I is I+1. 

· I is 6, J is I+1. 

Only two of these are actually valid queries - make sure you understand why. 
Defining your own relations

The relations positive and non_zero that we defined above represent things which would be regarded as relations in most languages. However, it's important to remember that in Prolog all "operations" must be represented as relations - this can seem a little strange at first.

Suppose we wanted to define a predicate to calculate the minimum value of two numbers. In C/C++, we might write a function of the form: 

  int minimum(int x, int y)

  {

    if (x < y) 

      return x;

    else 

      return y;

  }

This function takes two arguments and returns one value. In Prolog we don't' have functions, so this has to be represented as a relation. The first two arguments to the relation will be the input values, the third argument will be the result. Thus we note that: 

· In general, a function that takes k arguments will be represented in Prolog as a relation that takes k+1 arguments (the last one being used to hold the result) 

Thus in Prolog we write: 

  % minimum(X,Y,Z) is true if Z is the minimum of X and Y
  minimum(X,Y,X) :- X<Y.

  minimum(X,Y,Y) :- X>=Y.

We should read a statement of the form "minimum(X,Y,X) :- ..." as saying"the minimum of X and Y is X if ...". Note the way that the two alternatives are expressed as separate clauses in Prolog. 

It's a bit like if we insisted that all our functions in C/C++ were to be of type void, and return their result by pointers or reference; thus in C++ we might write*: 

  void minimum(int x, int y, int& z)

  {

    if (x < y) 

      z = x;

    else 

      z = y;

  }

Remember also that these predicates cannot be used in expressions like functions; in C/C++ we might write something like "(minimum(x,y) > 0)" to test if the minimum of two numbers is positive, since we know that minimum(x,y) represents a value. You should be very careful not to do this in Prolog, since applying the predicate minimum to something will not give a value. The corresponding Prolog expression is: minimum(X,Y,Z), Z>0. 

* Note: In the C version of the min function, we'd use pointers rather than reference parameters, so we might phrase the signature as void minimum(int x, int y, int* z). Thanks to Boris Glawe for pointing this out. 
Exercises
Define predicates to calculate the following: 

1. the result of adding 1 to a number 

2. the function signum(x) which is x-1 if x>0, and 0 otherwise. 

3. the maximum of two numbers 

4. the maximum of three numbers 

5. the absolute value of a number 

6. The following well-known recursive functions: 

	(a) Factorial:
	fact(0) 
= 
1 
fact(n) 
= 
n*fact(n-1), 
when n>0 


	(b) The Fibonacci function:
	fib(0) 
= 
1 
fib(1) 
= 
1 
fib(n) 
= 
fib(n-1)+fib(n-2), 
when n>1


	(c) Ackermann's function:
	Ack(0,y) 
= 
y+1
Ack(x,0) 
= 
Ack(x-1,1) 
when x >0
Ack(x,y) 
= 
Ack(x-1,Ack(x,y-1)) 
when x,y>0 



Section 6: Recursion

In this tutorial we simply want to practice using recursion. This is really important in Prolog, and we'll be using it a lot from now on, so you should try and work through all of the following... 

Using Recursion

In imperative languages like C/C++/Java we deal with situations which require iteration by means of constructs like while, do, for and so on. Prolog does not use these imperative-style constructs: instead, when we need to iterate, we use recursion. Recursion can take a little time to get used to, but it will be used in almost every non-trivial Prolog program from now on. 

Basically recursion involves defining something in terms of itself. The key to ensuring that this makes sense is that you always define something in terms of a smaller copy of itself. Recursion is the algorithmic equivalent of "proof by induction" in maths. 

When you do recursion you must have three things: 

1. Some set (or "data structure") over which you are doing the recursion: common examples include numbers, arrays, trees etc. 

2. A base case definition, usually dealing with an empty structure 

3. A recursive case definition, explaining how to work out a non-trivial case in terms of some smaller version of itself. 

Some Examples
Factorial: 

By definition, the factorial of some number n, written n! is n*n-1*n-2* ... *1. We can express this in terms of recursion as follows: 

· Data Structure: natural numbers 

· Base Case: 0! = 1 

· Recursive Case: For any n>0, we have n! = n * (n-1)! 

Note that we define n! in terms of (n-1)!. This is OK to do, since we know that (n-1) < n 

Even: 

We do not always have to decrease by 1 each time. For example, we can define a test to see whether a number is even as follows: 

· Data Structure: natural numbers 

· Base Case: 0 is even 

· Recursive Case: For any n>0 we know that n is even only if n-2 is even. 

A similar definition to test if a number is odd would only need to change the base case to refer to 1 rather than 0. 
Sequential Search: 
Suppose we want to search some section of an array A (say between location m and n) to see if an element E is present 

· Data Structure: section of an array 

· Base Case: m>n, in which case the answer is "no" 

· Recursive Case: m < n, in which case we say that if A[m]=E then return "yes", otherwise search between m+1 and n. 

Exercise:

1. Euclid's algorithm to calculate the greatest common divisor of two numbers can be stated as follows: 

	gcd(x,y) = 
	x, when x=y 
gcd(x-y,y), when x>y 
gcd(x,y-x), when y>x 


2. Going back to the family tree example, write a predicate which gives all the direct ancestors of a person i.e. their parents, grandparents, great-grandparents etc. (be sure to use recursion!) 

The Towers of Hanoi
This is an old chestnut: 

A group of over-proud monks in a Hanoi monastery were assigned a task to perform: they had to move 100 discs from one peg to another with the help of a third peg. There are only two rules: 

1. Only one disc can be moved at a time 

2. The discs are all of different sizes, and no disc can be placed on top of a smaller one 

We want to write a Prolog program to solve this; moreover, we suggest that recursion will help us to do this. In fact, posing it as a recursive problem simplifies matters considerably.

· Data Structure: The number of discs to be moved 

· Base Case: One disc - To transfer a stack consisting of 1 disc from peg A to peg B, simply move that disc from A to B 

· Recursive Case: To transfer a stack of n discs from A to B, do the following: 

· Transfer the first n-1 discs to some other peg C 

· Move the last disc on A to B 

· Transfer the n-1 discs from C to peg B 

Thus, when we wish to transfer n discs we assume that we already know how to transfer n-1 discs. 

To see that this works, let's code it in Prolog.

In Prolog...

Since our knowledge of I/O is fairly narrow, we'll just write out the instructions for each move. Let's define a predicate that will write out one instruction: 

  % move(A,B) is true if we move the topmost disc from peg A to peg B

  move(A,B) :-

    nl, write('Move topmost disc from '),

    write(A), write(' to '), write(B).

Now to actually do the main work, we'll define a recursive predicate which will have the form transfer(N,A,B,I) where: 

· N is the number of discs to be transferred 

· A is the peg on which the discs are stacked 

· B is the peg we are to move the discs to 

· I is the (empty) intermediate peg to be used for storage 

Basically, transfer(N,A,B,I) will be satisfied if we can find an algorithm to transfer N discs from A to B using I 

Thus we define: 

  % transfer(N,A,B,I) is true if we can transfer N discs from A to B

  %                   using I as an intermediate peg.

  % Base case - 1 disc

  transfer(1,A,B,I) :- move(A,B).

  % Recursive case - N discs

  transfer(N,A,B,I) :-

    M is N-1, 

    transfer(M,A,I,B),  % Transfer topmost N-1 discs from A to I
    move(A,B),          % Move biggest disc from A to B
    transfer(M,I,B,A).  % Transfer remaining N-1 discs from I to B
Type this in (save it as hanoi.pl), and try the query: 

  transfer(3,peg1,peg2,inter).

The Grid Example
Imagine a grid consisting of (evenly spaced) horizontal and vertical lines; assume that it is possible to place an object at the intersection of any two lines. Suppose also that the lines are potentially infinite in length. 

A possible configuration of objects on the grid might be: 

         |       |       |       |       |       |    

         |       |       |       |       |       |    

     ----+------[A]-----[B]------+------[C]------+----

         |       |       |       |       |       |    

         |       |       |       |       |       |    

         |       |       |       |       |       |    

     ----+------[D]-----[E]-----[F]-----[G]------+----

         |       |       |       |       |       |    

         |       |       |       |       |       |    

         |       |       |       |       |       |    

     ----+-------+------[H]------+-------+-------+----

         |       |       |       |       |       |    

         |       |       |       |       |       |    

         |       |       |       |       |       |    

     ----+-------+------[I]------+-------+-------+----

         |       |       |       |       |       |    

         |       |       |       |       |       |    

Suggest an appropriate format for a Prolog knowledge base that will represent this. Rather than using absolute co-ordinates (remember - it's infinitely large in theory), describe the position of the objects relative to each other (after all, Prolog is a relational language...) 

Think along the lines of the family tree example: make sure that you separate the facts which describe a given situation, from the rules which will work in any situation. 

Now write some rules which will check the following (you might already have expressed some of these as facts): 

1. an object is immediately to the right of another 

2. an object is immediately to the left of another 

3. an object is immediately above another 

4. an object is immediately below another 

5. an object is exactly between two others, either in a horizontal or vertical direction 

6. an object is directly beside another in a diagonal direction 

Finally, generalise the above so that they return all objects to the right/left or above/below another (using recursion!).
Section 7: Structures

Much of the information that we want to represent in a program is compound, that is, it consists of entities which have a number of different attributes. 

For example, the person entity might have a number of attributes such as age, height, weight, and so on. 

In languages like C we represent this information using structs; in an OO language we'd probably use a class. In Prolog we use structures. 

In general, a structure can appear in a clause anywhere a variable or constant would appear: it is another form of term. Thus, using a structure in Prolog corresponds to an instance of a class in an OO language. 

As with all other terms we have used in Prolog, structures do not need to be declared; we can simply use them wherever we want. 

The General Form of a Structure
A structure has the form: 

  structure-name ( attribute, ..., attribute )

Note
Note that structures look like predicates, but they work differently. Remember: predicates represent relationships; structures (and other terms) represent objects. 

Prolog tells the difference between predicates and structures only by seeing where they appear in a clause. Structures (just like any other terms) never appear on their own: they must always appear as the argument to some predicate. 

Arithmetic "Functions" and Structures

You might have noticed that Prolog does not treat structures any differently during unification from the arithmetic functions (like log or cos) that we met in the last tutorial. This is due to the declarative nature of Prolog: log(10) represents an object, not a computation, and thus can be treated like any other object. 

This represents an important difference from imperative languages: in Prolog it is important to think of terms like log(10) as structures rather than function-calls when it comes to unification. 

A simple example of using structures

Suppose we want to represent cars with attributes make, age, price. 

We might use a three-place structure called car; e.g. car(ford, 3, 5000) might represent a 3-year-old Ford selling for $5,000. 

Structures of this type could be used in clauses such as: 

  % has(P,C) is true if P has a car matching C

  has(joe, car(ford,3,5000)).

  has(joe, car(opel,2,6000)).

  has(mick, car(toyota,5,1000)).

  has(mick, car(ford,2,2000)).

And we can pose queries like: "What kind of Ford does Mick have?" 

Query: has(mick, car(ford, Age, Price)) 
Answer: Age=2, Price=2000 

If we only want to get information about some fields we can use Prolog's "don't care" marker - the underscore character - to indicate this. 

| ?- has(Person, car(ford,_,_)).

Person = joe ? ;

Person = mick

yes

The underscore "_" has indicated to Prolog that we aren't fussy about what matches these fields (and that we don't want to know what does). 

If we wanted to know what make of car sold for under 5000, we might ask: 

| ?- has(_, car(Make,_,Price)), Price < 5000.

Make = toyota

Price = 1000 ? ;

Make = ford

Price = 2000

yes

Exercises

1. Type the "car" example above into a Prolog program (called car.pl; try some queries to make sure you understand what is happening. Also, try adding a "colour" field to the structure. 

2. Data on each employee of a company consists of the following: employee's name, department in which s/he works, her/his position in the department (secretary, head, accountant etc.), number of years of service, basic salary, and the name of their immediate boss. The company director is his/her own boss! 

Write a Prolog database containing the employees' information (make up 5 or 6 entries) - this should be a list of facts containing "employee-details" structures. Now, based on this, make up some rules to answer the following: (the name of the rule, along with its arity is given in each case) 

· department/2: Find the department in which some particular person works 

· manager/2: Given a person's name, find out who's the manager of the department in which they work 

· valid_employee/1: Your list of facts should ideally form a tree; that is, if we get a person's boss, and then their boss' boss and so on, we should end up with the company director. Write a predicate which, when given a person's name, will check if this is so. 

· basic_salary/2: Get a person's basic salary 

· real_salary/2: Get a person's real salary, by adding the information that: 

· All employees with over 5 years service get a bonus of $5,000 

· No employee (even after bonuses) can earn more than his/her boss - use the "min" predicate here, and make sure to have a special case for the director... 

Section 8: Recursive Structures

In this section we look at how recursion can be used with structures to implement some common data structures. 

Even though lists are actually built in to Prolog (we'll be looking at this in the next tutorial), we can implement them ourselves using structures. 

We'll suppose for the purpose of this discussion that we're dealing with lists of numbers. Each node in the list will have two components: its contents, and a reference to the next node in the list. In addition we'll assume that the empty list is called nil. Thus, if we use a two-pace structure called node to represent a single node, a list containing the numbers 2, 6 and 7 would look like: 

  node(2, node(6, node(7, nil)))
Note that the smallest possible list is nil, and every other list will contain nil as the "next field" of the last node. In list terminology, the first element is usually called the head of the list, and the rest of the list is called the tail. Thus the head of the above list is 2, and its tail is the list node(6, node(7, nil)) 
Inserting an element
Suppose we want to write a predicate that adds a new element onto the head of the list; we should end up with a new list in which the input list is the tail. Thus we get: 

  % add_front(List,Elem,NewList) is true if NewList is List with Elem inserted at the beginning

  add_front(List,Elem,NewList) :- NewList = node(Elem,List).

Adding the element at the end of the list takes a little more effort, since we need to pass down through all the elements to find the last one, and add it in there. There are two cases: 

1. The input list is empty, in which case we create a new list with just one element 

2. The input list has one or more elements; i.e. it is of the form node(Head,Tail). In this case we recursively add the element to the tail Tail. 

Thus our code looks like: 

  % add_back(List,Elem,NewList) is true if NewList is List with Elem inserted at the end

  add_back(nil, Elem, NewList) :- 

    NewList = node(Elem,nil).   % New list with 1 element

  add_back(node(Hd,Tl), Elem, NewList) :- 

    add_back(Tl, Elem, NewTl),  % Add Elem to the tail of the list

    NewList = node(Hd,NewTl).   % Answer is Hd along with the new tail
Note that we have used some of Prolog's pattern-matching power here, since we expect it to choose between the two predicates based on whether the input list looks like either nil or node(H,T). No list can match both these patterns. 

Save the above predicates and load them into Prolog; now try the following queries to test that they work: 

· add_front(nil, 5, L1), add_front(L1, 7, L2), add_front(L2, 8, L3). 

· add_back(nil, 5, L1), add_back(L1, 7, L2), add_back(L2, 8, L3). 

· add_front(nil, 5, L1), add_front(L1, 7, L2), add_back(L2, 8, L3). 

Exercises
Write predicates to: 

1. get the first element in a list 

2. get the last element in a list 

3. sum all the elements in a list 

4. add an element to a list in order (that is, assuming the original list was ordered, the new one will still be ordered). 

Binary Trees

A binary tree will be like a list, except that each node will have two links to other trees - one to the left subtree, and one to the right. 

Thus, if we had the following tree: 

             2

             |

          +--+--+

          |     |

          1     6      

                |

          +-----+-----+

          |           |

          4           7

        +-+-+

        |   |

        3   5

we would represent it as: 
node(2, node(1,nil,nil), node(6, node(4,node(3,nil,nil), node(5,nil,nil)), node(7,nil,nil))

Often a binary tree will be ordered so that for any given node, the contents of its left-subtree will all be less than the current node, and the contents of the right will be greater than it. The tree shown above is ordered in this way. 
Exercise

1. Write a predicate tree_insert(Tree,Elem,NewTree) which is true if NewTree is the tree you get by adding the element Elem to the tree Tree so as to preserve its ordering. Remember that there will now be three cases: 

· If the tree is empty, add the element at the root 

· If the tree isn't empty, and Elem is less than the element stored at the current node, then add Elem to the left subtree 

· If the tree isn't empty, and Elem is greater than the element stored at the current node, then add Elem to the right subtree 

Try running the following queries: 

· tree_insert(nil,4,T1), tree_insert(T1,5,T2), tree_insert(T2,2,T3), tree_insert(T3,7,T4). 

· tree_insert(nil,7,T1), tree_insert(T1,5,T2), tree_insert(T2,4,T3), tree_insert(T3,5,T4). 

· tree_insert(nil,2,T1), tree_insert(T1,4,T2), tree_insert(T2,5,T3), tree_insert(T3,7,T4). 

Notice how lop-sided the last tree is - clearly the structure of the tree depends on the sequence in which we insert its elements... 

2. Write a predicate that calls write/1 for each element stored on the tree, so that it prints out all elements in order 

3. Write a predicate that gets the sum of all the elements on the tree 

4. Write a program that gets the height of the tree; i.e. the maximum length of any path from the root to a leaf. 

Section 9: Introducing Lists

We have already met structures; lists are Prolog's other built-in data type. 

Format of Lists
A list is simply an ordered, extendable sequence of terms; they correspond (roughly) to vectors in C++/Java. 

Remember that lists, like anything else which represents objects in Prolog, are terms. Thus we don't need to "declare" them, we just use them when needed. 

We write a list in Prolog using the brackets "[" and "]", and separate the elements by commas. As with any term, they must only appear in a clause as arguments to a predicate. 

Thus [john, mary, pat] is a list with three elements. 

List elements do not all have to look the same: ['string', 6, mary, X] is also a valid list. In fact, a list element may be any kind of term: that is, a constant, variable, structure, or even another list. 

Empty and Non-Empty Lists
There is one special unique list in Prolog called the empty list, written "[ ]". This is the list which contains no elements. 

Every non-empty list can be separated into two parts: 

· the head, which is the first element 

· the tail, which is the list containing all the other elements 

Thus:
The head of [john, mary, pat] is john
The tail of [john, mary, pat] is [mary, pat]. 

It is not valid to try and get the head or tail of the empty list. 

In Prolog we have a special notation just for dividing up lists: 

· [Hd | Tl] denotes the list whose head is Hd and whose tail is (the list) Tl. 

Thus the list [john, mary, pat] can also be written as [john | [mary,pat]]. 

Since [mary, pat] is also a list with head mary and tail [pat] (a one-element list), we can also write the above list as: [john | [mary | [pat]]] 

Any one-element list can be written as that element joined to the empty list; thus [pat] is the same as [pat | []], and so we can write the full list as: [john | [mary | [pat | []]]] 

This type of division is used in predicates which process lists; these take advantage of the unification rules for lists: 

· The only term that unifies with [] is [] 

· A list of the form [H1|T1] will only unify with a list of the form [H2|T2], and then only if H1 unifies with H2 and T1 unifies with T2 

As a consequence of these rules, we note that [] can never be the same as a list of the form [H|T] (for any element H and list T). 

Some Examples

Almost all predicates which use lists are recursive; they are defined for: 

· The base case: the empty list [] 

· The recursive case: for a list of the form [H|T], perform some action on the head H, then call the predicate recursively with the tail T 

The length of a list

Suppose we wanted to write a predicate size(L,N) meaning "the size of list L is N" (by size we mean the number of elements it contains). 

The size of the list is exactly equal to the number of times we can perform the head/tail division before we get the empty list. 

We can write: 

  % size(List,N) is true if List has N elements

  size([],0).

  size([H|T],N) :- size(T,N1), N is N1+1.

To paraphrase: 

· The size of the empty list is 0. 

· The size of the list whose head is H and whose tail is the list T is: 1 + (the size of T). 

Type in this definition, and try it on some examples... 

Summing a list
Suppose we know that a list contains only numbers; we should then be able to write a predicate that will get the sum of those numbers... 

This will be a little like the size/2 predicate, except now at each stage we want to add in the current element to the total. Thus we write: 

  % sumlist(List, N) is true if the elements of List sum to N

  sumlist([],0).

  sumlist([H|T],N) :- sumlist(T,N1), N is N1+H.

List Membership
Similarly we can define the predicate contains(X,L) which is true if X is an element of the list L. 

We observe that X is contained in L if 

· X is the head of L, or 

· X is in the tail of L. 

Thus we write: 

  % contains(Elem, List) is true if List contains Elem

  contains(X,[X|_]).

  contains(X,[_|T]) :- contains(X,T).

In other words: 

· X is a member if the list whose head-element is X (and whose tail is anything). 

· X is a member of the list whose head is anything and whose tail is T if X is a member of T. 

Note that we did not have to define a predicate for the case where the list was empty, because this case could never be true. (That is, contains will fail if the list is empty). 

Type in the contains predicate, and try entering the following queries: 

· contains(2, [1,2,3]) 

· contains(E, [1,2,3]) 

· contains(E, [2,1,2]) 

· contains(E, []) 

Exercises

Let L be any list of terms. Define Prolog predicates for the following: 

1. average(L,N) is true if N is the average of all the numbers in L, or just 0 if the sum is 0 

2. sumpos(L,N) is true if N is the sum of all the positive numbers in L 

3. sumsquare(L,N) is true if N is the sum of the squares of all the numbers in L 

4. maxlist(L,N) is true if N is the largest element in the list L. 

5. maxpos(L,N) is true if N is the position of the largest element in the list L. (If there's more than one occurrence of the maximum, then this should be the first position at which it appears.) 

6. final(L,E) is true if E is the final element in L 

7. evenpos(L) which prints out the elements of L at positions 2,4,6... up to the end of the list (Use write/1 to print out the elements.) 

Section 10: Lists as Accumulators

In the previous tutorial we have concentrated on moving through lists and processing their elements in the usual head/tail fashion. In this section we want to look at predicates that build new lists. 

Collecting information
Suppose we wanted to write a predicate that took a single argument, and printed out all the numbers between it and 0. We might write: 

  % print_to(N) - prints out all the numbers down from N to 0

  print_to(0) :- write(0).

  print_to(N) :- N>0, write(N), nl, N1 is N-1, print_to(N1).
If we try running this we would get something like: 
| ?- print_to(5).

5

4

3

2

1

0
Now suppose we wanted to take these numbers and process them in some other part of the program; to do this we would have to store them somewhere - the natural choice is to use a list. Thus we'd want a predicate of the form collect_to(N,L) where N was the input number, and L was the list containing the answer. 

This will be slightly different to the other list predicates, since now we want to build a list as we iterate, rather than take one apart. However, the process will still use the standard "[H|T]" notation that we have been using. 

We should work it out int he usual recursive manner: 

· Base Case: If the number entered is just 0, then the answer will be just [0], so we write: 

·   collect_to(0,L) :- L=[].

· Recursive Case: If we're dealing with a number, say N, then we can assume that we know how to collect all the numbers up to N-1 (thanks to recursion) so we just need to know how to add on the extra bit of information about the current element; the code looks like: 

·   collect_to(N,L) :- N>0, N1 is N-1, collect_to(N1,T), L=[N|T].
The above solution is correct, but as you get used to lists in Prolog you'll find ways to take advantage of its pattern-matching; the more common way of writing this predicate would be: 

  new_collect_to(0,[]).

  new_collect_to(N,[N|T]) :- N>0, N1 is N-1, new_collect_to(N1,T).

You should try both of these to make sure that they work, and that they both do the same thing! If the second, more compact version doesn't seem so natural, then you can stick to the first (longer) method of defining this kind of predicate for the moment. 

Joining two lists
We can write a predicate to join two lists together; the predicate join_list(L1,L2,L3) means "if we join L1 and L2 we get L3". 

If we consider the possibilities for L1 

1. L1 is the empty list, in which case L3 is just L2 

2. L1 is of the form [H1 | T1]. 
If we are to append L2 on to the end of this we will get a list whose head is still H1, but whose tail is the result of appending T1 and L2 

Thus an initial attempt might be: 

  join_list(L1,L2,L3) :- L1=[], L3=L2.

  join_list(L1,L2,L3) :- L1=[H1|T1], join_list(T1,L2,T3), L3=[H1|T3].

Since we know that Prolog will do unification when it matches parameters against arguments, a simpler (but equivalent) solution would be: 

  join_list([], L2, L2).

  join_list([H1|T1], L2, [H1|L3]) :-  join_list(T1,L2,L3).

Type in the join_list predicate, and try the following queries: 

· join_list([1,2],[6,7],X). 

· join_list(X, [5,6], [3,5,6]). 

· join_list([3,4], Y, [3,4,5,6]). 

· join_list(X,Y,[1,2]). 

Prolog has a built-in version of this predicate called append/3. 

Reversing a List
Another good example of accumulating results in a list is a predicate to reverse a list. Presumably the predicate will be of the form reverse(L1,L2), where L2 is just L1 backward. 

One rather bad way of doing this would be: 

  % bad_reverse(L1,L2) -  a bad implementation of list reversal

  bad_reverse([],[]).

  bad_reverse([H|T], L2) :-

    bad_reverse(T,NT), append(NT,[H],L2).
The problem with this is that it works rather inefficiently - the second predicate goes through the tail once to reverse it (putting the result into NT), and then again in order to stick H onto the end. 

If we think about the problem for a while, we can see that we need to go through L1, and put each element that we met into L2; for example, reversing the list [1,2,3] should go something like: 


Input

Output


-----

------


[1,2,3]

[ ]


[2,3]

[1]


[3]

[2,1]


[ ]

[3,2,1]
Unfortunately, there's no real way of doing this with just two lists. What we need to do is to mimic the "Towers of Hanoi" example a little, and use an intermediate list to store the answer that we're creating. When we're done, we can just copy this to the output list. 

In the Prolog library, there's an implementation of this as follows: 

%   myreverse(?List, ?Reversed)

%   is true when Reversed is has the same element as List but in a reversed 

%   order. List must be a proper list.

good_reverse(List, Reversed) :-


good_reverse(List, [], Reversed).

good_reverse([], Reversed, Reversed).

good_reverse([Head|Tail], SoFar, Reversed) :-


good_reverse(Tail, [Head|SoFar], Reversed).

I've called this good_reverse/2 to stop it clashing with the built-in reverse/2 predicate. 

The last two predicates above actually have three arguments (the input list, an intermediate list, and the output list), and so are different from the first one (which only has two). What happens here is that the user calls the first predicate, and this then calls the three-argument version with the empty list as the starting point for the intermediate storage. good_reverse/3 then copies the first list into the intermediate until it's empty, and then copies the intermediate list to the output list. 

Make sure that you understand this example - try running the following version (which prints out what it's doing) with some queries... 

%   pr_reverse(?List, ?Reversed)

%   is true when Reversed is has the same element as List but in a reversed 

%   order. List must be a proper list.

pr_reverse(List, Reversed) :-


pr_reverse(List, [], Reversed).

pr_reverse([], Reversed, Reversed) :-

        format("\nInput=~q, Intermediate=~q, Output=~q",[[],Reversed,Reversed]).

pr_reverse([Head|Tail], SoFar, Reversed) :-

        format("\nInput=~q, Intermediate=~q, Output=~q",[[Head|Tail],SoFar,Reversed]),


pr_reverse(Tail, [Head|SoFar], Reversed).

Here, format/2 is a built-in printing predicate that works a little like printf in C or Java. 

Exercises

1. Write predicates for the following: 

1. cutlast(L1,L2) which is true if L2 is L1 with the last element removed 

2. trim(L1,N,L2) which is true if L2 contains just the first N elements of L1 

3. evens(L1,L2) which is true if L2 contains just those elements in L1 which are even in the same order 

2. Write a predicate beg_small(L1,L2) which is true if L2 has the smallest number in L1 as its head, and all the other numbers in the same order 

3. Use recursion and the last predicate to implement a predicate that sorts a list by iteratively moving the smallest element to the head, then the next smallest to the second position and so on. 

4. Write a predicate split(L1,N,L2,L3) which is true if L2 contains those elements of L1 less than or equal to N, and L3 contains those elements of L1 greater than N. (This is a lot like the ordered binary trees example.) 

5. Use the last predicate to implement a quicksort as follows: 

1. Sorting the empty list gives you the empty list 

2. To sort a list of the form [H|T], call split(T,H,T1,T2), sort T1 and T2, and then append these along with H (in the middle) together to form the answer. 

Built-In list predicates
Many of the predicates that you will most commonly use when working with lists (such as those in the previous section) are built-in to Prolog. 

You might notice the format of the definitions; for example length(?list, ?integer). This not only gives a hint as to the expected type of the arguments to the predicate, but also to their "mode". The notation is pretty standard: 

Section 11: Backtracking and Cut
Prolog differs from imperative languages (like C) in that it concentrates on dealing with facts and rules, rather than sequences of instructions. However, for efficiency, it can sometimes be desirable to add explicit control information to programs - this is the purpose of the cut. 

Analysing Cases

Suppose you were asked to write a Prolog program that would take in someone's exam mark and work out their grade. It might look something like the following: 
  grade(Mark, first) :- Mark>=70.

  grade(Mark, two_1) :- Mark<70, Mark>=63.

  grade(Mark, two_2) :- Mark<63, Mark>=55.

  grade(Mark, third) :- Mark<55, Mark>=50.

  grade(Mark, pass)  :- Mark<50, Mark>=40.

  grade(Mark, fail)  :- Mark<40.
While this will work, it is a little inefficient. The query grade(75,G) will answer G=first as expected but, once this has been satisfied, Prolog will go back to look for any other solutions. In order to do this it will process all of the other options, failing during the body of the rule in each case. 

If we were implementing this in an imperative language we might try using a "switch" statement as follows: 

  // This code is somewhat artificial for the purpose of comparison

  int fir(int n) { return n>=70; }

  int fir(int n) { return n<70 && n>=63; }

  //  ... fill in the rest ...

  int fai(int n) { return n<40; }

  switch(n) {

    case(fir(n)): cout << "1st"; break;     

    case(tw1(n)): cout << "2.1"; break;     

    case(tw2(n)): cout << "2.2"; break;     

    case(thi(n)): cout << "3rd"; break;     

    case(pas(n)): cout << "Pass"; break;     

    case(fai(n)): cout << "Fail";

  }

Here we explicitly indicate that after one result has been accepted, we need not look at any of the others at all - this is the purpose of the "break" statement in each branch. 

We can do something similar in Prolog to improve efficiency. Basically, we want to tell Prolog that once it has satisfied one version of the predicate, it need look at no other. Prolog's equivalent of the break statement here is the cut, written "!". 

To eliminate useless backtracking from the above, (and taking advantage of Prolog's order of execution) we can rephrase the program as: 

  grade(N,first) :- N>=70, ! .

  grade(N,two_1) :- N>=63, ! .

  grade(N,two_2) :- N>=55, ! .

  grade(N,third) :- N>=50, ! .

  grade(N,pass) :- N>=40, ! .

  grade(N,fail) :- N<40.
The cut predicate has the effect of telling Prolog not to pass back through this point when it is looking for alternative solutions. Thus, the "!" acts as a marker, back beyond which Prolog will not go. When it passes this point all choices that is has made so far are "set"; i.e. they are treated as though they were the only possible choices. 

Note that the cut always appears where a predicate can appear (never, for example, as arguments to a predicate). It is treated at this level just like any other predicate, and it alwayssucceeds. 

In summary, the effect of the cut is as follows: 

1. Any variables which are bound to values at this point cannot take on other values 

2. No other versions of predicates called before the cut will be considered 

3. No other subsequent versions of the predicate at the head of the current rule will be considered 

4. The cut always succeeds. 

Basically, any more answers to the current query must come from backtracking between the point of the cut and the end of the current rule. 

An Example Of Using The Cut
Save the following knowledge base in a file, and read it into Prolog: 

  holiday(friday, may1).

  weather(friday, fair).

  weather(saturday, fair).

  weather(sunday, fair).

  weekend(saturday).

  weekend(sunday).

  % We go for picnics on good weekends and May 1st

  picnic(Day) :- weather(Day,fair), weekend(Day).

  picnic(Day) :- holiday(Day,may1).
Pose the query: 
  picnic(When).
You should get three answers; make sure you understand where they come from! Note that in order to get this answer, Prolog had to work through exactly one unsuccessful instantiation of When with "friday", before getting it right the second time. 

The First Cut
Now change the definition of picnic to the following: 

  picnic(Day) :- weather(Day,fair), !, weekend(Day).

  picnic(Day) :- holiday(Day,may1).
Now when we pose the query: Picnic(When) Prolog will try to satisfy the sub-goal: 

  weather(When,fair), !, weekend(When).
The first rule for weather is: 

  weather(friday,fair), 
so the new sub-goal becomes: 
  ....., !, weekend(friday).
Prolog passes the cut, and goes on to try to satisfy 

  weekend(friday)
which fails. Previously, it would have backtracked to the last choice point, and gone on with processing 
  weather(saturday,fair)
But now the presence of the cut stops it going back, so it is trapped between the cut and the end of the (failed) predicate. 

The answer now is simply: 

  No.

(Check that this is so...) 

Another Cut
Change the definition of picnic for a second time to get: 
  picnic(Day) :- weather(Day,fair), weekend(Day), !.

  picnic(Day) :- holiday(Day,may1).
With the same query Prolog proceeds as before, until it gets to the sub-goal: 
  ....., weekend(friday), !.
This time we go on to process: 
  weekend(friday)
which fails, and so we go back to the last choice point without meeting the cut. 

Since we also have: 

  weather(saturday,fair).
the new sub-goal becomes: 
  ....., weekend(saturday), !.
This time the whole goal succeeds, and Prolog processes the cut. Since there is a successful answer, Prolog prints out: 
  When = saturday.
However, because it has met the cut, it cannot go back, and so it will not return any extra answers. (Check this...) 

Yet Another Cut
Finally, change the definition of picnic once more, to get: 
  picnic(Day) :- !, weather(Day,fair), weekend(Day).

  picnic(Day) :- holiday(Day,may1).
This time when we ask picnic(When) the first thing we do is to process the cut, and Prolog puts down the "no going back" marker. Any solutions we get from now on have to come from between the "!" and the end of the clause. 

As before 

  weather(friday,fair)
fits, and so we try to satisfy: 
  weekend(friday)
which fails. We backtrack to the last choice point, which was for the goal: 
  weather(Day,fair)
Since we can get back here without passing the cut, we are free to consider the alternatives, and ultimately get: 
  When = saturday.

  When = sunday.
Note that the second attempt to get the answer friday never happens, because getting to the goal for this would involve crossing the cut, which we can't do. 

Thus there are only two solutions in this case. 

Exercises

1. Assume that we have a Prolog program with the following facts: 

2.   p(a).  q(a,1).  r(1,1).  r(3,5). 

3.   p(b).  q(a,2).  r(1,2).  r(3,6). 

4.          q(b,3).  r(2,3).  r(4,7). 

5.          q(b,4).  r(2,4).  r(4,8). 

What are the results of running the following queries? 

1. p(X), q(X,Y), r(Y,Z). 
2. !, p(X), q(X,Y), r(Y,Z). 

3. p(X), !, q(X,Y), r(Y,Z). 

4. p(X), q(X,Y), !, r(Y,Z). 

5. p(X), q(X,Y), r(Y,Z), !. 
6. Consider the following program which is intended to define the third argument to be the maximum of the first two numeric arguments: 

7.   max(X,Y,X) :- X >= Y, !.

8.   max(X,Y,Y).

1. Provide an appropriate query to show that this program is incorrect (try using all constant arguments) 

2. Change the program so that it works correctly 

9. Consider the following program which is supposed to insert its first argument, a number, into its second argument, a sorted list, giving the third argument (also a sorted list): 

10.   insert(X,[H|T],[H|T1]) :- X>H, !, insert(X,T,T1).

11.   insert(X,L,[X|L]).

1. Provide an appropriate query to show that this program is incorrect 

2. Change the program so that it works correctly 

Section 12: More Control Features

The cut predicate has a number of associated predicates, all of which deal with changing the way Prolog goes about solving goals. Use these sparingly! 

Kinds of cut
While using the cut can make programs shorter or more efficient, it also makes them more difficult to understand, and less "logical" in nature. In general we distinguish two types of cut: 
Green cuts 
These are cuts which are introduced simply to make the program more efficient by eliminating what the programmer knows to be useless computations. They do not remove any extra solutions! Running a program without green cuts should still give the same answer, even though it may take a little longer to do so. 
Red cuts 
These cuts are introduced to make the program run in a different way; they do this by eliminating some of the possibilities that might be considered. Thus they change the logical meaning of the program. 
Green cuts are useful for speeding up computations; red cuts should be avoided where possible. 

Negation as Failure
If we ask Prolog to satisfy some goal P, and Prolog responds no, we take this as meaning that P cannot be satisfied. 

In certain situations we will want to define predicates in terms of the negation of other predicates. 

We can do this using a combination of cut and another built-in predicate, fail, which always fails. 

Thus to say "q is true if p isn't", we might write: 

  q :- p, !, fail.

  q.

Note that if we left out the cut here then Q would always be satisfied, since the second case would be reached after the first failed. 

Prolog has a built-in shorthand for this: the meta-predicate "\+"; thus we might write: 

  q :- \+(p).    % Q is true whenever P fails...

An example of using this would be the following predicate which will be satisfied if X and Y cannot be unified. 
  different(X,Y) :- X=Y, !, fail.

  different(X,Y).

Warning!
This way of implementing what is effectively the predicate "not" is called negation as failure; it is not proper negation. As with any Prolog program involving the cut, you should be very careful when using it! 

An example of where negation as failure can give unexpected results is the following predicate: 

  home(X) :- \+(out(X)).

  out(sue).

Now, work out what is the logically correct answer to the following queries, and then try them in Prolog: 

· Is Sue at home? 

· Is John at home? 

· Is anyone at home? 

The apparent contradiction is caused by Prolog's closed-world assumption; that is, Prolog assumes it always has all relevant information: hence, if something can't be proved true, it must be false. 

If-then-else in Prolog
One common use of the cut predicate is to mimic the "if-then-else" construct found in imperative languages. 

Suppose we want to define some predicate S which should be of the form: "if P then Q else R" We can define this in Prolog as: 

  s :- p, !, q.

  s :- r.
Prolog has a shorthand for this built-in; we need only write: 
  s :- p -> q ; r.
For example, suppose we wanted to write a predicate to add an element to a list; we might just write: add(Elem,List,[Elem|List]). 

Suppose now that we want to change this predicate so that no duplicates are added to the list; we might write: 

  % add(Elem, List, NewList) is true if adding Elem to List is NewList

  %                          Elem is not added if it's there already.

  add(X,L1,L2) :- member(X,L1), !, L2 = L1.

  add(X,L1,L2) :- L2 = [X|L1].
Using the if-then-else notation, we could simply write this as: 
  add(X,L1,L2) :- member(X,L1) -> L2 = L1 ; L2 = [X|L1].

The repeat predicate
If a particular clause can be satisfied more than once, we know that Prolog will go back and try and find all of those solutions (assuming there is no cut). However, in certain circumstances it can be useful to get "all the backtracking done" on a particular part of the program, before moving on to process the rest of the goal. This sort of situation arises when we want to perform iterative operations like reading from a file, or some kind of "control loop" such as displaying a menu. 

Prolog has a built-in predicate called repeat, which can be satisfied arbitrarily many times. 

[Aside: the predicate is defined as: 

  repeat.

  repeat :- repeat.

] 

the predicate is generally used on the right-hand-side of some clause in the format: 

  ..... :- repeat,

           ( "Stuff to be iterated" ),

           ( "Termination Condition" ),

           !.

When the goal is processed, the repeat command is satisfied, and the "body" is processed. If the termination condition is true, then the execution of this block is finished - the cut ensures that we don't backtrack over it again. If it is false then backtracking occurs. Since the repeat will always be re-satisfied, control moves forward again from this point, and the process starts over. 

An common example might involve a structure like: 

  main_loop :- repeat,              % Start of iteration

                 display_menu,        % Print out the menu

                 get_option(N),       % Get input from user

                 validate_option(N),  % Check that it's valid

                 process_option(N),   % Carry out appropriate action

               is_quit_option(N),   % Termination Condition

               !.                   % Don't go back on any of this!
Here we assume that is_quit_option(N) returns true whenever N is the menu option corresponding to "Quit program"... 

The control predicates are described in section 7.18 of the GNU Prolog Manual.
Section 13: Input and Output
More on I/O
We have already seen the predicate write(X) which will write X onto the current output. There is a corresponding predicate read(X) which reads the current input (up to the next full-stop), and stores the result in X. 

File I/O
Prolog calls any source or destination of data a stream. Both the read and write predicates work with the "current" input and output streams which, by default, are the keyboard and the screen. To read/write to a file, it is simply necessary to make that file the "current" stream. 

The predicates to do this are as follows: 

· see(F) opens the file F for reading, and makes it the "current" stream 

· seen closes the current file that you are reading from, and resets the "current" input to be the keyboard 

· tell(F) opens the file F for writing, and makes it the "current" stream 

· told closes the currently-opened file that you are writing to, and resets the "current" stream to be the screen 

The special Prolog constant end_of_file is returned when you have read all data from a file. 

Saving and Restoring a Knowledge-Base
As an example of reading from a file, here's a program which mimics Prolog's "consult file" operation, reading the clauses from a file into the internal database (and printing them as it does so). 

  consult(F) :- see(F),

                repeat,

                  read(X),

                  nl, write(X),

                  assert(X),

                X=end_of_file,   %Termination condition for repeat

                !, seen.

Saving a knowledge base is achieved by opening the relevant file, and using the predicate listing which will print all the currently-defined clauses the the current output stream. 

There is a specialised version of listing which takes one argument: a list of those predicates whose definitions we want to see. Thus, to save the facts from the family tree example to the file fam.pl, we might enter: 

  tell('fam.pl'), listing([parent/2, male/1, female/1]), told.

Other Approaches to I/O
There are a number of ways of doing I/O in Prolog; the predicates described above comprise what's known as "Dec-10 I/O" (named after one of the early machines on which Prolog was implemented). You should consult the list of built-in predicates in the GNU Prolog Manual for more sophisticated versions of I/O. 

An Exercise
Go back to the family tree example, and enhance it using what you have leaned about lists, changing the knowledge-base and I/O. That is, you should change it so that: 

· We no longer have separate parent/male/female facts, but just one fact of the form person(N,S,L), where N is the person's name, S is either male or female, and L is a (possibly empty) list of their children's names 

· The user is presented with a menu, allowing for the following operations: 

· Add a new person (should ask if male/female); validate that they are not already in the knowledge base 

· Delete a person from the knowledge base 

· Add the information that X is a child of Y 

· Remove X from the list of children of Y 

The add/delete operations can be implemented using assert and retract. You might also add a "Clear all" option, implemented using abolish. 

· Finally, add options that will allow a person to save the current family tree to a file, or read it in from an existing file. 

Don't try and do all of this in one go - use some of your Software Engineering skills to design the system first!

